Doorbell /ringer by smartphone/pc


Description

In this tutorial is shown how to play a buzzer via a Smartphone/PC using an Arduino UNO WiFi

Warning:
Please, it's important to upgrade to the latest ESP firmware, using the Arduino UNO firmware updater tool, before to continue this tutorial.

Hardware 

You can also use the component of the  WorkShop kit or use a Tinkerkit Buzzer.
For more details visit our Store.

Circuit

Use a breadboard to place the buzzer and connect it via wires to the board or connect directly the Buzzer on the Pin 9 and GND as shown in the below image :

buzzer circuit


buzzer tutorial

Instead if you want to use a Tinkerkit Buzzer then follow these indications:
Normally the Tinkerkit devices have three pins Vcc(+), the Signal and the Ground (-). 
Connect the Vcc pin (+) to 5V, the Ground (-) to GND and the other to the pin 9 of the board, you can use the wires female/male for the connections.


Code

Now connect the board to PC, via USB cable, and upload the below code, using the Arduino IDE (click here for download the sketch):

Warning:
If you are using the Arduino IDE 1.7.x then continue to use the ArduinoWiFi.h library.
Instead if you are using the Arduino IDE 1.8.x then download the UNOWiFiDev.Edition library from Library Manager and modify the code, replacing #include <ArduinoWiFi.h> with #include <UnoWiFiDevEd.h>


/*
Doorbell/ringer by smartphone/PC
Upload the code and open your borwser on http://<IP>/arduino/webserver/ or http://<hostname>.local/arduino/webserver/
for more information:
http://www.arduino.org/learning/tutorials/boards-tutorials/doorbell-ringer-by-smartphone-pc

created in November 2016
by sebba[at]arduino[dot]org

*/

//Import libraries
#include <Wire.h>
#include <ArduinoWiFi.h>// if you are using the Arduino IDE 1.8.x then: //#include <UnoWiFiDevEd.h>
#include "pitches.h"

#define PIN 9
int melody[] = {NOTE_C4, NOTE_G3, NOTE_G3, NOTE_A3, NOTE_G3, 0, NOTE_B3, NOTE_C4};

// note durations: 4 = quarter note, 8 = eighth note, etc.:
int noteDurations[] = { 4, 8, 8, 4,4,4,4,4 };

//SET UP
void setup() {
pinMode(PIN, OUTPUT); //connect the buzzer on Pin 9
Wifi.begin();
Wifi.println("WebServer Server is up");
digitalWrite(PIN, LOW);
}


//LOOP
void loop() {
while (Wifi.available()) {
process(Wifi);//call process() function
}
delay(50);
}

/* FUNCTIONS */

//process()
void process(WifiData client) {
// read the command
String command = client.readStringUntil('/');
if (command == "webserver") {
WebServer(client);// call WebServer() function
}
if (command == "digital") {
digitalCommand(client);//call digitalCommand() function
}
}

//WebServer()
void WebServer(WifiData client) {
client.println(F("<html><head><style>"));

//Stylesheet parameters for the button
client.println(F("input[type=button]{font-size:62px;color:#FFF;width:50%;margin:20% 0 0 25%;}"));
client.println(F(".off{background:#666; pointer-events:none}"));
client.println(F(".on{background:#00979C}"));
client.println(F("</style>"));

/*
JavaScript functions that creates an Ajax request to the URL
URL+'/arduino/digital/'+pin+'/'+value"
where URL is the IP of the Uno WiFi, pin is the pin to change and value is the logic level
of the pin
*/
client.println(F("<script>"));

//This function create the command for the AJAX request
client.println(F("function command(event,pin){"));
client.println(F("var value=document.getElementById(event.id).value=='ON'?0:1"));
client.println(F("ajax(event.id,pin)}"));

//Create the AJAX request
client.println(F("function ajax(elm, pin){"));
client.println(F("var URL_array=document.URL.split('/')"));;
client.println(F("var URL=URL_array[0]+'//'+URL_array[2]"));
client.println(F("url=URL+'/arduino/digital/'+pin+'/1'"));
client.println(F("xmlhttp=new XMLHttpRequest()"));
client.println(F("xmlhttp.onreadystatechange=function(){"));
client.println(F("if(xmlhttp.readyState==4 && xmlhttp.status==200)"));
client.println(F("var resp=xmlhttp.responseText"));
client.println(F("if(typeof resp==='undefined')return"));
client.println(F("document.getElementById(elm).className='on'}"));
client.println(F("document.getElementById(elm).className='off'"));
client.println(F("xmlhttp.open('GET',url,true)"));
client.println(F("xmlhttp.send()"));
client.println(F("}</script>"));

//Print the HTML Code, with the button. Pushing the button it calls the function "command"
client.println(F("</head><body>"));
client.print(F("<input id=button class=on type=button onClick='command(this,"));
client.print(PIN);
client.println(F(")' value='BUZZER'> "));
client.println(F("</body></html>"));
client.println(DELIMITER); //end communication
client.flush();
}

/*
digitalCommand() function
It plays the melody
*/
void digitalCommand(WifiData client) {
int pin, value;

// Read pin number
pin = client.parseInt();

// If the next character is a '/' it means we have an URL with a value like: "/digital/13/1"
if (client.read() == '/') {
value = client.parseInt();
if(pin==PIN){
for (int thisNote = 0; thisNote < 8; thisNote++) {
// to calculate the note duration, take one second divided by the note type, e.g. quarter note = 1000 / 4, eighth note = 1000/8, etc.
int noteDuration = 1000/noteDurations[thisNote];
tone(pin, melody[thisNote],noteDuration);

// to distinguish the notes, set a minimum time between them.
// the note's duration + 30% seems to work well:
int pauseBetweenNotes = noteDuration * 1.30;
delay(pauseBetweenNotes);
// stop the tone playing:
noTone(pin);
}

client.print(F("HTTP/1.1 200 OK\n"));
client.print(F("Play"));
client.print(EOL);
}
}
}

Create or  to import the pitches.h file.
Put the pitches.h file into the same folder of the sketch. 

/*************************************************
* Public Constants
*************************************************/

#define NOTE_B0 31
#define NOTE_C1 33
#define NOTE_CS1 35
#define NOTE_D1 37
#define NOTE_DS1 39
#define NOTE_E1 41
#define NOTE_F1 44
#define NOTE_FS1 46
#define NOTE_G1 49
#define NOTE_GS1 52
#define NOTE_A1 55
#define NOTE_AS1 58
#define NOTE_B1 62
#define NOTE_C2 65
#define NOTE_CS2 69
#define NOTE_D2 73
#define NOTE_DS2 78
#define NOTE_E2 82
#define NOTE_F2 87
#define NOTE_FS2 93
#define NOTE_G2 98
#define NOTE_GS2 104
#define NOTE_A2 110
#define NOTE_AS2 117
#define NOTE_B2 123
#define NOTE_C3 131
#define NOTE_CS3 139
#define NOTE_D3 147
#define NOTE_DS3 156
#define NOTE_E3 165
#define NOTE_F3 175
#define NOTE_FS3 185
#define NOTE_G3 196
#define NOTE_GS3 208
#define NOTE_A3 220
#define NOTE_AS3 233
#define NOTE_B3 247
#define NOTE_C4 262
#define NOTE_CS4 277
#define NOTE_D4 294
#define NOTE_DS4 311
#define NOTE_E4 330
#define NOTE_F4 349
#define NOTE_FS4 370
#define NOTE_G4 392
#define NOTE_GS4 415
#define NOTE_A4 440
#define NOTE_AS4 466
#define NOTE_B4 494
#define NOTE_C5 523
#define NOTE_CS5 554
#define NOTE_D5 587
#define NOTE_DS5 622
#define NOTE_E5 659
#define NOTE_F5 698
#define NOTE_FS5 740
#define NOTE_G5 784
#define NOTE_GS5 831
#define NOTE_A5 880
#define NOTE_AS5 932
#define NOTE_B5 988
#define NOTE_C6 1047
#define NOTE_CS6 1109
#define NOTE_D6 1175
#define NOTE_DS6 1245
#define NOTE_E6 1319
#define NOTE_F6 1397
#define NOTE_FS6 1480
#define NOTE_G6 1568
#define NOTE_GS6 1661
#define NOTE_A6 1760
#define NOTE_AS6 1865
#define NOTE_B6 1976
#define NOTE_C7 2093
#define NOTE_CS7 2217
#define NOTE_D7 2349
#define NOTE_DS7 2489
#define NOTE_E7 2637
#define NOTE_F7 2794
#define NOTE_FS7 2960
#define NOTE_G7 3136
#define NOTE_GS7 3322
#define NOTE_A7 3520
#define NOTE_AS7 3729
#define NOTE_B7 3951
#define NOTE_C8 4186
#define NOTE_CS8 4435
#define NOTE_D8 4699
#define NOTE_DS8 4978

If you want to use an external webserver, for example Apache, then use this other code.

OUTPUT

buzzer button
  • Push on the Buzzer button to play the doorbell.

Note: 

If you haven't configured your board then click here.